mirror of
https://github.com/Zenithsiz/ftmemsim-valgrind.git
synced 2026-02-03 10:05:29 +00:00
461cc5c003
Sync VEX/LICENSE.GPL with top-level COPYING file. We used 3 different addresses for writing to the FSF to receive a copy of the GPL. Replace all different variants with an URL <http://www.gnu.org/licenses/>. The following files might still have some slightly different (L)GPL copyright notice because they were derived from other programs: - files under coregrind/m_demangle which come from libiberty: cplus-dem.c, d-demangle.c, demangle.h, rust-demangle.c, safe-ctype.c and safe-ctype.h - coregrind/m_demangle/dyn-string.[hc] derived from GCC. - coregrind/m_demangle/ansidecl.h derived from glibc. - VEX files for FMA detived from glibc: host_generic_maddf.h and host_generic_maddf.c - files under coregrin/m_debuginfo derived from LZO: lzoconf.h, lzodefs.h, minilzo-inl.c and minilzo.h - files under coregrind/m_gdbserver detived from GDB: gdb/signals.h, inferiors.c, regcache.c, regcache.h, regdef.h, remote-utils.c, server.c, server.h, signals.c, target.c, target.h and utils.c Plus the following test files: - none/tests/ppc32/testVMX.c derived from testVMX. - ppc tests derived from QEMU: jm-insns.c, ppc64_helpers.h and test_isa_3_0.c - tests derived from bzip2 (with embedded GPL text in code): hackedbz2.c, origin5-bz2.c, varinfo6.c - tests detived from glibc: str_tester.c, pth_atfork1.c - test detived from GCC libgomp: tc17_sembar.c - performance tests derived from bzip2 or tinycc (with embedded GPL text in code): bz2.c, test_input_for_tinycc.c and tinycc.c
158 lines
3.8 KiB
ArmAsm
158 lines
3.8 KiB
ArmAsm
|
|
/*--------------------------------------------------------------------*/
|
|
/*--- CPUID interface. m_cpuid.S ---*/
|
|
/*--------------------------------------------------------------------*/
|
|
|
|
/*
|
|
This file is part of Valgrind, a dynamic binary instrumentation
|
|
framework.
|
|
|
|
Copyright (C) 2000-2017 Julian Seward
|
|
jseward@acm.org
|
|
|
|
This program is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
This program is distributed in the hope that it will be useful, but
|
|
WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
General Public License for more details.
|
|
|
|
You should have received a copy of the GNU General Public License
|
|
along with this program; if not, see <http://www.gnu.org/licenses/>.
|
|
|
|
The GNU General Public License is contained in the file COPYING.
|
|
*/
|
|
|
|
#include "pub_core_basics_asm.h"
|
|
|
|
/*
|
|
Bool VG_(has_cpuid)(void)
|
|
*/
|
|
#if defined(VGA_x86)
|
|
.text
|
|
.globl VG_(has_cpuid)
|
|
VG_(has_cpuid):
|
|
pushl %ebp
|
|
movl %esp, %ebp
|
|
pushl %ecx
|
|
pushfl
|
|
pushfl
|
|
popl %eax
|
|
movl %eax, %ecx
|
|
xorl $0x200000, %eax
|
|
pushl %eax
|
|
popfl
|
|
pushfl
|
|
popl %eax
|
|
popfl
|
|
xorl %ecx, %eax
|
|
andl $0x200000, %eax
|
|
shrl $21, %eax
|
|
popl %ecx
|
|
movl %ebp, %esp
|
|
popl %ebp
|
|
ret
|
|
#elif defined(VGA_amd64)
|
|
.text
|
|
.globl VG_(has_cpuid)
|
|
VG_(has_cpuid):
|
|
movq $1, %rax
|
|
ret
|
|
#endif
|
|
|
|
/*
|
|
void VG_(cpuid)(UInt eax, UInt ecx,
|
|
UInt* eax_ret, UInt* ebx_ret, UInt* ecx_ret, UInt* edx_ret)
|
|
*/
|
|
#if defined(VGA_x86)
|
|
.text
|
|
.globl VG_(cpuid)
|
|
VG_(cpuid):
|
|
pushl %ebp
|
|
movl %esp, %ebp
|
|
pushl %eax
|
|
pushl %ebx
|
|
pushl %ecx
|
|
pushl %edx
|
|
pushl %esi
|
|
movl 8(%ebp), %eax
|
|
movl 12(%ebp), %ecx
|
|
cpuid
|
|
movl 16(%ebp), %esi
|
|
testl %esi, %esi
|
|
jz 1f
|
|
movl %eax, (%esi)
|
|
1:
|
|
movl 20(%ebp), %esi
|
|
testl %esi, %esi
|
|
jz 2f
|
|
movl %ebx, (%esi)
|
|
2:
|
|
movl 24(%ebp), %esi
|
|
testl %esi, %esi
|
|
jz 3f
|
|
movl %ecx, (%esi)
|
|
3:
|
|
movl 28(%ebp), %esi
|
|
testl %esi, %esi
|
|
jz 4f
|
|
movl %edx, (%esi)
|
|
4:
|
|
popl %esi
|
|
popl %edx
|
|
popl %ecx
|
|
popl %ebx
|
|
popl %eax
|
|
movl %ebp, %esp
|
|
popl %ebp
|
|
ret
|
|
#elif defined(VGA_amd64)
|
|
.text
|
|
.globl VG_(cpuid)
|
|
VG_(cpuid):
|
|
pushq %rbp
|
|
movq %rsp, %rbp
|
|
pushq %rbx
|
|
movl %edi, %eax
|
|
movq %rcx, %rdi
|
|
movl %esi, %ecx
|
|
movq %rdx, %rsi
|
|
/*
|
|
eax_ret now in %rsi
|
|
ebx_ret now in %rdi
|
|
ecx_ret now in %r8
|
|
edx_ret now in %r9
|
|
*/
|
|
cpuid
|
|
testq %rsi, %rsi
|
|
jz 1f
|
|
movl %eax, (%rsi)
|
|
1:
|
|
testq %rdi, %rdi
|
|
jz 2f
|
|
movl %ebx, (%rdi)
|
|
2:
|
|
testq %r8, %r8
|
|
jz 3f
|
|
movl %ecx, (%r8)
|
|
3:
|
|
testq %r9, %r9
|
|
jz 4f
|
|
movl %edx, (%r9)
|
|
4:
|
|
popq %rbx
|
|
movq %rbp, %rsp
|
|
popq %rbp
|
|
ret
|
|
#endif
|
|
|
|
/* Let the linker know we don't need an executable stack */
|
|
MARK_STACK_NO_EXEC
|
|
|
|
/*--------------------------------------------------------------------*/
|
|
/*--- end ---*/
|
|
/*--------------------------------------------------------------------*/
|